Mindustry/ios/build.gradle

sourceSets.main.java.srcDirs = ["src/"]

ext{
    mainClassName = "mindustry.ios.IOSLauncher"
}

task copyAssets(){
    doLast{
        delete{
            delete "assets/"
        }
    
        copy{
            from "../core/assets"
            into "assets/"
        }
        
        exec{
            ignoreExitValue true
            commandLine "sh", "./convert_audio.sh", "assets/sounds"
        }
    
        exec{
            ignoreExitValue true
            commandLine "sh", "./convert_audio.sh", "assets/music"
        }
    
        delete{
            delete fileTree('assets'){
                include '**/*.ogg'
            }
        }
    }
}

task deploy{
    if(System.getProperty("os.name").contains("Mac")) dependsOn copyAssets
    dependsOn createIPA
}

launchIPhoneSimulator.dependsOn build
launchIPadSimulator.dependsOn build
launchIOSDevice.dependsOn build
createIPA.dependsOn build

robovm{
    archs = "thumbv7:arm64"

    if(project.hasProperty("signIdentity")) println "iOS Sign Identity: " + project.property("signIdentity")
    if(project.hasProperty("provisioningProfile")) println "iOS Provisioning Profile: " + project.property("provisioningProfile")

    iosSignIdentity = project.properties["signIdentity"]
    iosProvisioningProfile = project.properties["provisioningProfile"]
    iosSkipSigning = false
}